Ob ein Verb absolut oder relativ ist, hängt davon ab, ob es neben dem Subjekt auch noch andere Ergänzungen braucht, um einen vollständigen Satz zu bilden.

Absolute Verben brauchen neben dem Subjekt keine weiteren Ergänzungen, um einen vollständigen Satz zu bilden.
Relative Verben verlangen neben dem Subjekt noch weitere Ergänzungen, um einen vollständigen Satz zu bilden.

Ach so ja, um Verben geht es hier ja gar nicht, aber… hm, ach ja… Excel, ja - geht ja schon los… denn bei den Bezugsarten von Excel ist es genau anders herum als bei Verben:

Relative Bezüge brauchen neben der Zelladresse keine weiteren Ergänzungen in einer Formel.
Absolute Bezüge brauchen neben der Zelladresse noch weitere Ergänzungen in einer Formel.

So, jetzt aber mal im Ernst: In Excel rechnet man in der Regel mit Zellbezügen und nur sehr selten mit festen Zahlen. Die Zellbezüge oder Zelladressen werden normalerweise in der Schreibweise A2 oder B15 angegeben. Formeln, die mit einem so geschriebenen Zellbezug aufgebaut werden, passen sich an, wenn die Formeln kopiert werden. Der so angegebene Bezug ist relativ. Excel unterscheidet grundsätzlich zwei verschiedene Bezugsarten: relative und absolute Bezüge. Abgeleitet davon gibt es Mischbezüge, bei denen ein Teil des Bezugs relativ, ein anderer absolut ist.

Was ist denn jetzt relativ, was absolut?

Excel sieht in einem relativen Bezug nicht wirklich die Zelladresse B4 oder C6, sondern eine Wegbeschreibung. Die Ergebniszelle ist der Ausgangspunkt!

Angenommen in Zelle B3 steht die Formel "=A1".

A B C 1       2       3   =A1   4

Dann "denkt" Excel folgendermaßen:

Gehe zwei Zeilen nach oben
Gehe nun in dieser Zeile eine Zelle nach links.
Zeige den Inhalt dieser Zelle an.

Schlecht nachvollziehbar, stimmt! Am Besten kann man das verfolgen wenn man in Excel ausnahmsweise die Z1S1-Bezugsart aktiviert.
(Extras - Optionen, Karteireiter "Allgemein" - Kontrollkästchen vor Z1S1-Bezugsart aktivieren)

Die Formel "=A1" sieht jetzt so aus:
(Man beachte die veränderte Spaltenbeschriftung: Spalte B = Spalte 2!)

1 2 3 1       2       3   =Z(-2)S(-1)   4

Jetzt werden wir in dieser Darstellung rechnen - die Formel "=A1-C4" sieht so aus:

1 2 3 1       2       3   =Z(-2)S(-1)-Z(1)S(1)   4

Und so denkt Excel jetzt:

Gehe zwei Zeilen nach oben. Z(-2)
Gehe in dieser Zeile eine Zelle nach links. S(-1)
Nimm diese Zahl als erste Ziffer.

Gehe eine Zeile nach unten. Z(1)
Gehe in dieser Zeile eine Zelle nach rechts. S(1)
Nimm diese Zahl als zweite Ziffer.


Kopiert man die Zelle B3 jetzt irgendwo hin, dann verhält sich die Formel wie ein Strickmuster:

2 hoch, 1 links, schnapp diese Ziffer - dann 1 runter, 1 rechts, schnapp diese Ziffer…

"Strickmuster" in Z1S1-Bezugsart:

1 2 3 4 5 1           2           3   =Z(-2)S(-1)-Z(1)S(1)       4   =Z(-2)S(-1)-Z(1)S(1)       5   =Z(-2)S(-1)-Z(1)S(1)       6           7           8       =Z(-2)S(-1)-Z(1)S(1)   9

"Strickmuster" in A1-Bezugsart nicht erkennbar:

A B C D E 1           2           3   =A1-C4       4   =A2-C5       5   =A3-C6       6           7           8       =C6-E9   9

Wenn man einen relativen Bezug verwendet, weist man also Excel an, diesen Bezug automatisch zu verändern, wenn die Formel an eine andere Stelle kopiert wird.

Problematisch wird der relative Bezug, wenn man mehrere Berechnungen mit dem gleichen Zellinhalt machen möchte.
Im folgenden Beispiel soll jeweils der Wert aus C6 subtrahiert werden, die Formeln in B3 bis B5 werden manuell eingegeben. Da dies auf Dauer zu mühsam ist wird dann die Formel aus B5 einfach nach unten kopiert:

A B C D 1 10       2 9       3 8 8     4 7 7     5   6     6   #WERT! 2   7     Text   8         Formeln der Tabelle B3 : =A1-C6 B4 : =A2-C6 B5 : =A3-C6 B6 : =A4-C7

Da Excel aber prinzipiell den relativen Bezug zugrunde legt, bekommt man jetzt eine Fehlermeldung!
Excel geht wieder nach dem gleichen Muster vor wie oben und nimmt als zweite Ziffer den Wert aus "1 runter, 1 rechts".
Für die Berechnung in B5 passt das, aber in B6 ergibt "1 runter, 1 rechts" als Zellbezug die Zelle C7 in der keine Ziffer, sondern Text steht.
Excel kann aber schlecht rechnen: 7 minus "Text"...
Das Resultat ist deswegen eine Fehlermeldung. Man benötigt in einem solchen Fall eine andere Schreibweise der Zelladressen, den absoluten Bezug.

Der absolute Bezug muss selbst in die Formel eingegeben werden. Die Schreibweise ist $A$1 - die Dollarzeichen machen aus dem relativen einen absoluten Bezug. Damit wird Excel angewiesen, die Zelladresse nicht als Wegbeschreibung zu verstehen, sondern als fixe Anschrift.

Natürlich kann man die Dollarzeichen selbst über die Tastatur eingeben - aber das ist viel zu umständlich. Einfacher geht es wenn man in der Formel in B5 den Bezug "C6" markiert und die Taste F4 drückt - sie produziert die beiden Dollarzeichen. Dabei ist es egal, ob der Cursor direkt vor, in oder direkt hinter dem Bezug steht oder ob der Bezug insgesamt mit Doppelklick markiert ist.

Anschließend diese Formel nach unten kopieren. Die erste Zelladresse hat sich angepasst - sie ist relativ geblieben. Aus A3 wird A4, die zweite Zelladresse ($C$6) ist aber identisch.

A B C D 1 10       2 9       3 8 8     4 7 7     5   6     6   5 2   7     Text   8         Formeln der Tabelle B3 : =A1-C6 B4 : =A2-C6 B5 : =A3-$C$6 B6 : =A4-$C$6

Bei einem absoluten Bezug auf eine Zelle ist immer genau diese Zelle gemeint und keine andere.
Wenn man einen absoluten Bezug verwendet, bestimmt man, dass der Bezug beim Kopieren und Versetzen nicht verändert werden darf, sodass er sich immer auf dieselbe Zelle bezieht.

Relative und absolute Bezüge können in einer Adresse auch gemischt werden. Gemischte (oder teilabsolute) Bezüge werden beim Kopieren folgendermaßen behandelt:
Der absolute Teil des Bezugs bleibt unverändert, der relative Teil des Bezugs wird angepasst.


Bezugsart ändern

Wie schon weiter oben beschrieben einfach die gewünschte Zellbezeichnung in der Formel markieren und die Taste F4 drücken.
Wenn F4 mehrfach gedrückt wird, werden die möglichen Bezugsarten kreisförmig gewechselt.


Mögliche Bezugsarten:

A1	ist ein relativer Bezug auf die Zelle A1
$A$1	ist ein absoluter Bezug auf die Zelle A1
$A1	ist ein gemischter Bezug, bei dem der Bezug auf die Spalte absolut gesetzt ist, während der Bezug auf die Zeile relativ bleibt.
A$1	ist ein gemischter Bezug, bei dem der Bezug auf die Zeile absolut gesetzt ist, während der Bezug auf die Spalte relativ bleibt.

Wann welche Bezugsart?

Wann ist es notwendig, mit absoluten oder gemischten Bezügen zu arbeiten?

Am Beispiel der Mehrwertsteuerberechnung kann man am ehesten die Notwendigkeit von absoluten Bezügen nachvollziehen:
Im ersten Beispiel wurden im Bereich C4:E4 in allen Formeln relative Bezüge verwendet, die Formeln wurden einfach nach C5:E5 kopiert.
Da der Nettogesamtpreis immer durch Einzelpreis x Stückzahl und der Bruttogesamtpreis durch Addition von Netto Ges. und MwSt ermittelt wird, sind die durch die relativen Bezüge automatisch angepassten Formeln in C5 und E5 richtig "übersetzt" worden.
Die Mehrwersteuer in D4 wird durch "Netto Ges. x MwSt" (C4*B1) ermittelt. Die automatische Anpassung der relativen Bezüge macht daraus in D5 aber "C5*B2" - da in B2 aber nichts steht ist das eine Multiplikation mit Null!

A B C D E 1 MwSt: 19%       2           3 Einzelpreis Stückzahl Netto Ges. MwSt Brutto Ges. 4 4,95 25 123,75 23,51 147,26 5 100,00 2 200,00 0,00 200,00 6           Formeln der Tabelle C4 : =A4*B4 D4 : =C4*B1 E4 : =C4+D4 C5 : =A5*B5 D5 : =C5*B2 E5 : =C5+D5

Verwendet man jedoch in D4 für die Mehrwertsteuer den absoluten Bezug $B$1 bleibt dieser Bezug auch in den kopierten Zeilen erhalten:

A B C D E 1 MwSt: 19%       2           3 Einzelpreis Stückzahl Netto Ges. MwSt Brutto Ges. 4 4,95 25 123,75 23,51 147,26 5 100,00 2 200,00 38,00 238,00 6 100,00 2 200,00 38,00 238,00 7 25,50 7 178,50 33,92 212,42 8 75,80 9 682,20 129,62 811,82 Formeln der Tabelle C4 : =A4*B4 D4 : =C4*$B$1 E4 : =C4+D4 C5 : =A5*B5 D5 : =C5*$B$1 E5 : =C5+D5 C6 : =A6*B6 D6 : =C6*$B$1 E6 : =C6+D6 C7 : =A7*B7 D7 : =C7*$B$1 E7 : =C7+D7 C8 : =A8*B8 D8 : =C8*$B$1 E8 : =C8+D8

Hier noch das einfache Beispiel einer Kumulation der Bruttogesamtpreise:

A B C D E F 1 MwSt: 19%         2             3 Einzelpreis Stückzahl Netto Ges. MwSt Brutto Ges. Kumuliert 4 4,95 25 123,75 23,51 147,26 147,26 5 100,00 2 200,00 38,00 238,00 385,26 6 100,00 2 200,00 38,00 238,00 623,26 7 25,50 7 178,50 33,92 212,42 835,68 8 75,80 9 682,20 129,62 811,82 1.647,50 9             Formeln der Tabelle F4 : =SUMME($E$4:E4) F5 : =SUMME($E$4:E5) F6 : =SUMME($E$4:E6) F7 : =SUMME($E$4:E7) F8 : =SUMME($E$4:E8)

Durch eine geschickte Mischung von Bereichsbezügen können z. B. Aufsummierungen vorgenommen werden.

Im nächsten Beispiel werden in den Bezügen teils die Zeilennummern, teils die Spaltenbezeichnungen relativ benutzt:

A B C D 1 Menge 10 20 30 2 Rabatt 5% 6% 7% 3 Einzelpreis Stückpreis bei Abnahmemenge     4 4,95 4,7025 4,6530 4,6035 5 50,00 47,5000 47,0000 46,5000 6 100,00 95,0000 94,0000 93,0000 7 25,50 24,2250 23,9700 23,7150 8 75,80 72,0100 71,2520 70,4940 Formeln der Tabelle B4 : =$A4-($A4*B$2) C4 : =$A4-($A4*C$2) D4 : =$A4-($A4*D$2) B5 : =$A5-($A5*B$2) C5 : =$A5-($A5*C$2) D5 : =$A5-($A5*D$2) B6 : =$A6-($A6*B$2) C6 : =$A6-($A6*C$2) D6 : =$A6-($A6*D$2) B7 : =$A7-($A7*B$2) C7 : =$A7-($A7*C$2) D7 : =$A7-($A7*D$2) B8 : =$A8-($A8*B$2) C8 : =$A8-($A8*C$2) D8 : =$A8-($A8*D$2)

Dadurch, dass in der Formel in B4 die Zeilennummern für den Einzelpreis und die Spaltenbuchstaben für den Rabatt relativ benutzt werden, kann die Formel einfach in den gesamten Bereich B4:D8 kopiert werden und es wird in jedem Fall die richtige Berechnung durchgeführt.