Funktion "INDIREKT": Gibt den Inhalt einer Zelle wieder, dessen Adresse (in der A1 oder Z1S1 Schreibweise) in der Zelle zu lesen ist, die als „Bezug“ angegeben wird

zurück

Hört sich relativ kompliziert an, ist es aber nicht. Am Besten lässt sich das auch wieder am Beispiel erklären.
Aber zunächst die notwendigen Voraussetzungen:

Syntax
INDIREKT(Bezug;A1)

Bezug ist der Bezug auf eine Zelle, die einen Bezug in der A1-Schreibweise , oder in der Z1S1-Schreibweise,
einen definierten Namen als Bezug oder einen Zellbezug als Zeichenfolge enthält.
Gibt Bezug einen unzulässigen Zellbezug an, gibt INDIREKT den Fehlerwert #BEZUG! zurück.

Verweist Bezug auf eine andere Arbeitsmappe (ein externer Bezug) muss diese Arbeitsmappe geöffnet sein.
Ist die Quellarbeitsmappe nicht geöffnet, gibt die INDIREKT-Funktion den Fehlerwert #BEZUG! zurück.

A1 ist ein Wahrheitswert, der angibt, welche Art von Bezug in der Zelle enthalten ist.
Ist A1 gleich WAHR oder nicht angegeben, wird Bezug als ein Bezug interpretiert, der in der A1-Schreibweise vorliegt.
Ist A1 gleich FALSCH, wird Bezug als ein Bezug interpretiert, der in der Z1S1-Schreibweise vorliegt.
(In den folgenden Beispielen wird die A1-Schreibweise verwendet, da die Z1S1-Schreibweise eher ungebräuchlich ist)

A B C D E 1   A 10 z   2   B 9 y   3   Meier 8 x   4   C 7 w   5   D 6 v   6   E 5 u   7   F 4 t   8   G 3 s   9   H 2 r   10   I 1 q   11           12       55 =SUMME(INDIREKT("C1:C10")) 13

Die im vorstehenden Beispiel in Zelle D12 mittels der INDIREKT-Funktion angezeigte Summe des Bereichs "C1:C10"
liese sich mit der Funktion "=Summe(C1:C10)" genau so errechnen - mit einem entscheidenden Nachteil:

Wird die Spalte C (oder der Bereich "C1:C10") gelöscht, oder der genannte Bereich wird durch Verschieben eines
anderen Bereichs überschrieben, so wird die Funktion "Summe" den Fehlerwert "#BEZUG!" anzeigen!

Anders die INDIREKT-Funktion, die - als Summenformel verwendet - bedingt durch die Anführungszeichen in der
Formel =SUMME(INDIREKT("C1:C10")) z. B. beim Löschen einer Spalte trotzdem den vorgegebenen Bereich
als Berechnungsgrundlage einsetzt.


In der Funktion kann ein direkter Zellbezug oder eine Zellreferenz angegeben werden:

A B C 17 Beispiel 1 Direkte Bezugsangabe   18   Beispiel 1 =INDIREKT("A17") 19 A17 Beispiel 1 =INDIREKT(A19) 20   Inhalt von Tabelle4 - Zelle A5 =INDIREKT("Tabelle4!A5") 21

Die Formel in B18 zeigt den Inhalt der Zelle A17 an. Bedingt durch die Schreibweise (in Anführungszeichen gesetzter Bezug),
wird immer der Inhalt der Zelle A17 angezeigt!

In B19 nimmt die Formel den Inhalt der Zelle A19 (ohne Anführungszeichen!), die auf A17 verweist, als Referenz. Wird der
Inhalt der Zelle A19 z.B. in "B17" geändert würde der Inhalt der Zelle B17 (also "Direkte Bezugsangabe") als Ergebnis angezeigt.

In B20 wird der Inhalt von Zelle A5 in der Tabelle4 (der gleichen Arbeitsmappe) angezeigt. Auch hier wird, bedingt durch die
Anführungszeichen, immer der Inhalt von Zelle A5 in der Tabelle4 angezeigt werden - außer das Blatt "Tabelle4" wird gelöscht!


Ein Zellbezug kann aber auch aus mehreren Zellinhalten zusammengesetzt werden:

A B C 22 Beispiel 2 Blattname Zelle 23   Tabelle4 A5 24       25   Inhalt von Tabelle4 - Zelle A5 =INDIREKT(B23&"!"&C23&"") 26

Im angezeigten Ergebnis zeigt sich kein Unterschied zu B20 im vorherigen Beispiel. Allerdings ist die Formel in B25 wesentlich
flexibler als in B20. Durch ändern des Blattnamens in B23 kann, ohne Eingriff in die Formel, der Bezug auf ein anderes
Tabellenblatt vorgegeben werden. Ebenso kann durch Änderung von C23 eine andere Zelle angesprochen werden.
Durch &"!"& werden B23 und C23 entsprechend verkettet, das Ausrufezeichen muss in Anführungszeichen gesetzt werden.


Jedoch hat auch diese "Zusammensetzung" ihre Probleme sobald Leerzeichen oder Sonderzeichen ins Spiel kommen:

A B C 27 Beispiel 3 Blattname Zelle 28   47 11 A5 29       30   #BEZUG! =INDIREKT(B28&"!"&C28&"") 31   Inhalt von Blatt "47 11" - Zelle A5 =INDIREKT("'"&B28&"'"&"!"&C28&"") 32

In B30 steht faktisch die gleiche Formel wie in B25, durch das Leerzeichen im Blattnamen 47 11 versagt aber die Funktion.

Dem kann Abhilfe geschaffen werden indem man die Formel, wie in C31 angezeigt, anpasst.
Achtung: In der Formel =INDIREKT("'"&B28&"'"&"!"&C28&"") sind nicht zwei aufeinander folgende Anführungszeichen!
Diese schließen jeweils ein Hochkomma ein: " ' " (hier mit Leerzeichen zur besseren Lesbarkeit - in der Formel ohne Leerzeichen!)


Im nun folgenden Beispiel ist lediglich noch eine Aufteilung des Zellbezuges in Spalte und Zeile erfolgt:

A B C D 33 Beispiel 4 Blattname Spalte Zeile 34   47 11 A 5 35         36   Inhalt von Blatt "47 11" - Zelle A5 =INDIREKT("'"&B34&"'"&"!"&C34&D34&"")   37

Diese Aufteilung bringt eine noch höhere Flexibilität der INDIREKT-Funktion. Verwendet man die Funktion VERGLEICH in der
Zelle D34 so kann die Datenbasis jederzeit verändert werden und die Funktion bringt dennoch das richtige Ergebnis (natürlich nur
wenn die Struktur der Quelldaten an sich erhalten bleibt, also die gesuchten und zu vergleichenden Werte in den gleichen Spalten)


Abschließend noch ein Beispiel mit Bezug auf eine andere Arbeitsmappe:

A B C D E F 38 Beispiel 5 Verzeichnis Mappe Blattname Spalte Zeile 39   D:/Daten/Test/ MappeXY 47 11 A 5 40             41   Inhalt von "MappeXY" - Blatt "47 11" - Zelle "A5" im Verzeichnis "D:/Daten/Test/" =INDIREKT("'"&B39&"["&C39&"]"&D39&"'"&"!"&E39&F39&"") 42

Der Bezug auf die externe Mappe funktioniert aber nur solange die externe Mappe geöffnet ist, bzw. das Ergebnis bleibt nach
dem Schließen der externen Mappe nur bis zur nächsten Neuberechnung erhalten. Danach wird #BEZUG! angezeigt.
Die Angabe des Verzeichnisses ist optional, dient letztlich nur als Hilfsmittel zum Auffinden des Ablageortes der externen Mappe.
Die Formel funktioniert auch wenn das Ablageverzeichnis nicht angegeben wird.
Ohne Bezug auf B39 sieht die Formel so aus: =INDIREKT("'"&"["&C39&"]"&D39&"'"&"!"&E39&F39&"")